Copy the following VB coded MS Excel addin

Do not change it anyway

Press Ctrl+A (ie select all) after opening the file

Copy

Open MS Excel

Open Tool Menu / Macro / Visual Basic Editor

In the Visual Basic Editor, click Module on the Insert menu.

Then in the project list on the left hand side double click the Module 1

Past the copied code

Save the project as 

File Type            -             Microsoft Excel Add-in

File Name           -             “Currency Number to Text.xla”

Path                     -             Default

Exit the Visual Basic Window

Exit and restart Microsoft Excel

Now

Type any number

Open insert function wizard

Choose “User defined function” from the Function Categories

Choose “ConvertCurrencyToEnglish” in the function name list to convert the number in a given cell

Function ConvertCurrencyToEnglish(ByVal MyNumber)

Dim Temp

         Dim Rupees, Paise

         Dim DecimalPlace, Count

         ReDim Place(9) As String

         Place(2) = " Thousand "

         Place(3) = " Lac "

         Place(4) = " Crore "

         Place(5) = " Arawb "

         Place(6) = " Kharawb "

         Place(7) = " Neel "

         ' Convert MyNumber to a string, trimming extra spaces.

         MyNumber = Trim(Str(MyNumber))

         ' Find decimal place.

         DecimalPlace = InStr(MyNumber, ".")

         ' If we find decimal place...

         If DecimalPlace > 0 Then

            ' Convert Paise

            Temp = Left(Mid(MyNumber, DecimalPlace + 1) & "00", 2)

            Paise = ConvertTens(Temp)

            ' Strip off Paise from remainder to convert.

            MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))

         End If

            ' Convert digit of MyNumber to English Rupees.

            If Len(MyNumber) = 1 Then

            Digit = ConvertDigit(Right(MyNumber, 1))

            Rupees = Digit & Rupees

            End If

            ' Convert 2 digits of MyNumber to English Rupees.

            If Len(MyNumber) = 2 Then

            Tens = ConvertTens(Right(MyNumber, 2))

            Rupees = Tens & Rupees

            End If

            ' Convert remaining digits of MyNumber to English Rupees.

        If Len(MyNumber) >= 3 Then

            Hundreds = ConvertHundreds(Right(MyNumber, 3))

            Rupees = Hundreds & Rupees

            ' Remove last 3 converted digits from MyNumber.

            MyNumber = Left(MyNumber, Len(MyNumber) - 3)

            Count = 2

            Do While Len(MyNumber) > 1

            ' Convert last 2 digits of MyNumber to English Rupees.

            Temp = ConvertTens(Right(MyNumber, 2))

            If Temp <> "" Then Rupees = Temp & Place(Count) & Rupees

                ' Remove last 2 converted digits from MyNumber.

                MyNumber = Left(MyNumber, Len(MyNumber) - 2)

            'Else

            'MyNumber = ""

            Count = Count + 1

            Loop

            ' Convert last digit of MyNumber to English Rupees.

            If Len(MyNumber) = 1 Then

            Digit = ConvertDigit(Right(MyNumber, 1))

            Rupees = Digit & Place(Count) & Rupees

            End If

         End If

         ' Clean up Rupees.

         Select Case Rupees

            Case ""

               Rupees = "No Rupees"

            Case "One"

               Rupees = "One Rupee"

            Case Else

               Rupees = Rupees & " Rupees"

         End Select

         ' Clean up Paise.

         Select Case Paise

            Case ""

               Paise = " And No Paisa"

            Case "One"

               Paise = " And One Paisa Only "

            Case Else

               Paise = " And " & Paise & " Paise Only"

         End Select

         ConvertCurrencyToEnglish = Rupees & Paise

End Function

Private Function ConvertHundreds(ByVal MyNumber)

Dim Result As String

         ' Exit if there is nothing to convert.

         If Val(MyNumber) = 0 Then Exit Function

         ' Append leading zeros to number.

         MyNumber = Right("000" & MyNumber, 3)

         ' Do we have a hundreds place digit to convert?

         If Left(MyNumber, 1) <> "0" Then

            Result = ConvertDigit(Left(MyNumber, 1)) & " Hundred "

         End If

         ' Do we have a tens place digit to convert?

         If Mid(MyNumber, 2, 1) <> "0" Then

            Result = Result & ConvertTens(Mid(MyNumber, 2))

         Else

            ' If not, then convert the ones place digit.

            Result = Result & ConvertDigit(Mid(MyNumber, 3))

         End If

         ConvertHundreds = Trim(Result)

End Function

Private Function ConvertTens(ByVal MyTens)

Dim Result As String

         ' Is value between 10 and 19?

         If Val(Left(MyTens, 1)) = 1 Then

            Select Case Val(MyTens)

               Case 10: Result = "Ten"

               Case 11: Result = "Eleven"

               Case 12: Result = "Twelve"

               Case 13: Result = "Thirteen"

               Case 14: Result = "Fourteen"

               Case 15: Result = "Fifteen"

               Case 16: Result = "Sixteen"

               Case 17: Result = "Seventeen"

               Case 18: Result = "Eighteen"

               Case 19: Result = "Nineteen"

               Case Else

            End Select

         Else

            ' .. otherwise it's between 20 and 99.

            Select Case Val(Left(MyTens, 1))

               Case 2: Result = "Twenty "

               Case 3: Result = "Thirty "

               Case 4: Result = "Forty "

               Case 5: Result = "Fifty "

               Case 6: Result = "Sixty "

               Case 7: Result = "Seventy "

               Case 8: Result = "Eighty "

               Case 9: Result = "Ninety "

               Case Else

            End Select

            ' Convert ones place digit.

            Result = Result & ConvertDigit(Right(MyTens, 1))

         End If

         ConvertTens = Result

End Function

Private Function ConvertDigit(ByVal MyDigit)

Select Case Val(MyDigit)

            Case 1: ConvertDigit = "One"

            Case 2: ConvertDigit = "Two"

            Case 3: ConvertDigit = "Three"

            Case 4: ConvertDigit = "Four"

            Case 5: ConvertDigit = "Five"

            Case 6: ConvertDigit = "Six"

            Case 7: ConvertDigit = "Seven"

            Case 8: ConvertDigit = "Eight"

            Case 9: ConvertDigit = "Nine"

            Case Else: ConvertDigit = ""

         End Select

End Function

