
ADVANCED EXCEL FORMULA

SUMIF

Excel's SUMIF is one of it's most versatile and truly useful native worksheet functions. Here is one of the many ways it can be applied in yourprojects. 

Here's the scenario. Let's say you have a column of numbers (col A) -- both positive and negative values. How can you sum just the numbers meeting some criteria ... such as, only those greater than or equal to zero. 

Here's the formula ... 


=SUMIF(A:A,">=0",A:A)

The first argument tells Excel what range to evaluate. In this case, we're evaluating the entire column A. 

The second argument is your criteria. So, for our example it's all positive numbers ">=0" (notice the quotation marks). 

Finally, the third argument says what range to use to get the values to sum whenever your criteria is met. In our case, again it's all of column A. 

Here's the key to understanding the SUMIF function. The items to be added in the sum range corresponds to the index of the items matching the criteria in the evaluated range. In other words, if the fifteenth item in evaluated range satisfies your criteria then the value of the fifteenth item in the sum range will be included in the total returned by the formula.

CONDITIONAL AVERAGE

An AVERAGEIF worksheet function would be useful. But since it doesn't exist ( yet ) as a standard feature in Excel, we can create an equivalent. To do this, divide the result of a SUMIF function by the result of a COUNTIF function. 

Let's say you have the list of items with prices shown in the first two columns of this table. You need to be able to get the average price of all items of a color. In our example, we'll get the average of the "blue" items. 

So that you can avoid the need to hard code the criteria in your formula, in our example you can just enter the name of a color in cell C2. The result is being displayed in cell C5, where we've entered the following formula ... 


=SUMIF(A2:A8,C2,B2:B8)/COUNTIF(A2:A8,C2)

The first part of this formula returns the sum of the prices for all the "blue" items. We're evaluating the range containing the names of the colors in column A. In other words, this formula says ... 
look at the list in column A and if there's a match on the entry in cell C2 then include that item's corresponding value from column B in the addition. 


=SUMIF(A2:A8,C2,B2:B8)

The result is 18.00. 


The second half of this formula returns a count of the "blue" items. Again, we're evaluating the range containing the names of the colors in column A. So this part of the formula says ... 
look at the list in column A and if there's a match on the entry in cell C2 then count that item. 


COUNTIF(A2:A8,C2)

The result, of course, is 3. 


Finally, all that remains to be done is to divide the sum of items matching your criteria by the count of those same items. So, 18.00 / 3 = 6.00 -- the average price of "blue" items. 




One More Valuable Tip: 

To improve usability, you can try to use named ranges whenever it is possible and practical. For instance, in this example you may want to do something like this ... 
· A2:A8 = Colors 

· B2:B8 = Prices 

· C2 = Criteria 


... so your formula could be restated as ... 


=SUMIF(Colors,Criteria,Prices)/COUNTIF(Colors,Criteria)




If you are familiar with the use of an array formula, here's another approach to a conditional average. 
{=AVERAGE(IF(Colors=Criteria,Prices))}


Remember, you don't type the curly brackets {} and hold down the CTRL key and SHIFT key when entering your array formula. So, after you type the formula in the formula bar or range the last step will be CTRL + SHIFT + ENTER. 

In this case we're saying if an item's COLOR matches our CRITERIA, then include the PRICE amount in the array of values to be averaged. 

Otherwise, if any field in a record fails to meet our criteria, then the amount for that record will simply be ignored. FYI, the 3rd argument in an IF worksheet function is optional - it simply defaults to a FALSE if omitted. 

One thing to be aware of when using this formula is that the AVERAGE worksheet function will return a #DIV/0 error if there are not any records that satisfy your criteria. The workaround is to write a longer formula that traps the error and returns either a 0 (zero) or "" (empty quotes) if there are no records matching the criteria. Something like this ... 
{=IF(ISERROR(AVERAGE(IF(Colors=Criteria,Prices))),"",

                             AVERAGE(IF(Colors=Criteria,Prices)))}

SUM OR AVERAGE WITH MULTIPLE CRITERIA

Many Excel spreadsheet power-users are familiar with writing formulas that use the SUMIF worksheet function. What can you do when you need to get a set of values based on multiple criteria? 

In the first three columns of this worksheet, we have a DATE field, a field with an ACCOUNT number and a field with a dollar AMOUNT. 

In this problem, we'll want to write a formula to get the SUM from the AMT field of all records between our FROM DATE ( in cell E2 ) and the TO DATE ( in cell F2 ) ~and~ belonging to the ACCOUNT criteria ( in cell G2 ). 

For this demonstration, we'll start by writing a formula in H2 as follows: 


=SUM((A2:A19>=E2)*(A2:A19<=F2)*(B2:B19=G2)*C2:C19)


Now [ IMPORTANT before you hit the enter key] , you will need to use Ctrl + Shift + Enter instead. This creates an ARRAY FORMULA, recognizable by the curly brackets " { } " that automatically appear around it. You never type these curly brackets when entering an array formula. 

Here's how this array formula works - 

It evaluates each of the conditions as either TRUE or FALSE. A match on the criteria = 1 and anything else returns a 0 ( zero ). So, record that matches all the criteria, the evaluation of every individual record to something like this ... 

=1 * 1 * 1 * AMOUNT Field Value


... then the array formula gets the SUM of what is returned for all the records. 

If the record didn't match then it will have one or more of the criteria evaluating to a zero. Like so ... 

=1 * 1 * 0 * AMOUNT Field Value


... and, because the failure of a match on one of the criteria causes this record to be multiplied by zero, the resulting amount for that record to contribute to the sum of all the records is also zero. 

We can make the original formula more understandable by using named ranges, as follows: 
	RANGE NAME
	REFERS TO

	 rngDate
	 A2:A19

	 rngAcct
	 B2:B19

	 rngAmt
	 C2:C19

	 rngFromDate
	 E2

	 rngToDate
	 F2

	 rngAcctCriteria
	 G2



So, now we can write the formula this way: 
=SUM((rngDate>=rngFromDate)*(rngDate<=rngToDate)*(rngAcct=rngAcctCriteria)*rngAmt)




Now, using an array formula, let's use the same set of data and discover how to do an AVERAGE with multiple criteria: 
=AVERAGE(IF(rngDate>=rngFromDate,IF(rngDate<=rngToDate,

                                 IF(rngAcct=rngAcctCriteria,rngAmt))))


Again, you don't type the curly brackets {} and remember to hold down the CTRL key and SHIFT key when entering your array formula. So, after you type the formula in the formula bar or range the last step will be CTRL + SHIFT + ENTER. 

In this case we're nesting IF worksheet functions. So, we're saying if the FROM DATE, and the TO DATE, and the ACCOUNT number all match our criteria, then include the AMOUNT in the array of values to be averaged. 

Otherwise, if any field in a record fails to meet one of our criteria, then the amount for that record will simply be ignored. FYI, the 3rd argument in an IF worksheet function is optional - it simply defaults to a FALSE if omitted. 

One thing to be aware of when using this formula is that the AVERAGE worksheet function will return a #DIV/0 error if there are not any records that satisfy your criteria. The work around is to write a longer formula that traps the error and returns either a 0 (zero) or "" (empty quotes) if there are no records matching the criteria.
HIDING UNUSED ROWS & COLUMNS

Hiding rows and columns does not just have to be for concealing data or formulas. If your spreadsheet only uses a small area of the 16,777,216 available cells in an Excel worksheet, maybe it would be nice to hide some of that vast unused region to keep users from scrolling off the edge of your working area. 

Here are the simple steps to accomplish this task: 

1. Select the row header just beneath the used area of your spreadsheet, where you want to start hiding rows. 

2. Press Ctrl + Shift + Down Arrow. This will highlight everything from your selected row through the bottom of the worksheet. 

3. From the worksheet's Format menu, choose Row, then Hide. 

Follow the same basic steps to hide columns. The difference will be that you should begin by selecting a column header in the first empty column to the right of your used area, then press Ctrl + Shift + Right Arrow. 


MULTIPLE CRITERIA TEXT LOOK-UP

Let's say you need to return a text value from a list, in which there are multiple criteria used to determine which record provides that data. 

There are various options available for the task. Filtering could be the quick and easy way. And, developing a VBA procedure for the job would be another alternative. 

Nonetheless, we really just want a formula for this -- and, sometimes that makes the most appropriate solution. 

First, let's look at the data in the example I've set up. 

There are three all-TEXT fields: Company, Name, and E-Mail. We want to write a formula to return an e-mail address from the table, based on a combination of the Company and Name field values as criteria. 

Notice, the table has records for two companies, ABC CORP. and XYZ CORP., and both have someone named Charles Smith. 

Step 1 will be to create two named ranges - one encompasing the Company field and the other for the Name field. Dynamic Named Ranges would be ideal, but for the sake of a simple illustration we'll create a couple of conventional named ranges. 

From the worksheet's Insert menu choose Names then the Define... command. Enter a name for your new range. We'll use Sheet1!rngCompany and Sheet1!rngName. Next, in the Refers to: box, enter or select the following to be rngCompany : 


=Sheet1!$A$1:$A$7


... and, respectively, for rngName in our second field : 

=Sheet1!$B$1:$B$7


Step 2 will be for us to set-up another range, for entering the lookup criteria and our formula. We'll just move over a few columns for this. 

In cells E2 and F2 I've entered a Company and a person's Name. The combination of both of these will be our lookup criteria. 

In cell G2 I've entered the following as an array formula: 


=INDEX(C:C,MATCH(E2 & F2,rngCompany&rngName,0))


Now [ IMPORTANT before you hit the enter key] , you will need to use Ctrl + Shift + Enter instead. This creates an ARRAY FORMULA, recognizable by the curly brackets " { } " that automatically appear around it. You never type these curly brackets when entering an array formula. 

Here's how this works - 
· The key to the formula is concatenation of the criteria variables, also the lookup ranges. To concatenate means to join together. There is a CONCATENATE function for this purpose, but an ampersand ( & ) will work just the same. 

Therefore, instead of looking at two distinct fields, the formula will be treating the Company and Name as though it is a single field. 

The criteria will be the combination of cells E2 and F2. Concatenated, it looks like "ABC CORP.Charles Smith", stuck together. 


· The MATCH function returns the index number within the lookup array of the item matching the given criteria. 

We needed to get the MATCH function to treat the Company and Name fields as though they are just one field. We've done so by concatenating the named ranges - rngCompany & rngName. 

By the way, the MATCH function in this example gives us the value of 3. 


· Finally, the INDEX function with a zero as the 3rd argument, returns the item, from an array, corresponding to the index value argument (that will be the row number of the matching record). 

Our formula returns the 3rd item in range C:C, the E-Mail field. 

Note: We're counting the header (row 1), since it was also included in the criteria ranges. 


Finally, we can improve this formula by accomodating the possibility that there is no match in the lookup table. This formula is really one line, but it's shown as wrapped onto a second line so it will fit on this page. 
=IF(ISNA(INDEX(C:C,MATCH(E2 & F2,rngCompany&rngName,0))),"MISSING",


INDEX(C:C,MATCH(E2 & F2,rngCompany&rngName,0)))


Translating this to plain English, it says - 
"If a match is NOT found in the table, then display the word 'MISSING' instead of a function error." 

Another Approach 

It is unlikely, however possible, that a combination of the criteria could be the same when concatenated. 

In this example, the multiple criteria could be A & BC = ABC just as AB & C = ABC. 

Therefore, another approach would be in order. Referring to our original example, the array formula in range G2 could be: 

 =INDEX(C:C,MATCH(1,(E2=rngCompany)*(F2=rngName),0))

PREVENTING DUPLICATE ENTRY

Here is a technique to prevent duplicate entries within a range (which is easy to do if you're entering, let's say, invoice numbers). 

Suppose you want to prevent duplicate entries in the range A1:A10: 

1. Select cell A1 and choose the Validation command from the Data menu. 

2. Click the Data Validation dialog's Settings tab. 

3. In the Allow dropdown list, select Custom. 

4. In the Formula box, type:. 

5.    =NOT(OR(COUNTIF($A$1:$A$10,A1)>1))

6. Now you'll need to set an alert style. Click the Error Alert tab. 

7. Set the Style dropdown to Stop (the alert message with a 'Stop' sign on it). 

8. In the Title box, type what you want to appear in the Error Alert's title bar (for example, "Duplicate Entry"). 

9. In the Error message box, type the your text (for example, "This value already exists in the list"). 

10. Click OK. 

11. Finally, back in the worksheet, copy cell A1 down through A10. 

Now, you can test it by making an entry in a cell within A1:A10, then try to duplicate that entry in any other cell within the same range.

STANDARD DEVIATION IN EXCEL SPREADSHEETS 

Standard deviation shows up as one of this site's most sought topics. A statistician may find the following article gives it very basic treatment, but it's for the benefit of the rest of us mere mortals who work with Excel daily at our jobs. It's probable, that you'll gain a better appreciation for how you may use standard deviation. 

The ways standard deviation can be employed are infinite. Some common applications are: 

· Helping to quantify investment risk 

· Identifying the level of disparity in compensation programs 

· Almost any statistical analysis of demographic data 


The following chart will help you to visualize the concept. 

Standard deviation tells how tightly a set of values is clustered around the average of those same values. It's a measure of dispersal, or variation, in a group of numbers. 

Referring to the chart above. If a set of numbers (in this case, periodic temperature values) is close to the average of those values, then we may expect to see a low standard deviation. In contrast, if the set of numbers is spread across a greater range, it may present a high standard deviation. 

Higher standard deviation is often interpreted as higher volatility. In comparison, lower standard deviation would likely be an indicator of stability. The most consistent values will usually be the set of numbers with the lowest standard deviation. 


Calculating Standard Deviation "the Old Fashioned Way" 

Stick with me on this - because it will gain meaning once you see what's behind the standard deviation calculation. What's more, we will do it without ever using a bell curve diagram. 

Column B in the illustration below shows the average monthly temperature in Houston from January through August. We will calculate standard deviation using this data set. 

Here is how standard deviation gets calculated, in seven easy steps: 

1. Average the original data values 

- here it is the temperature observations in Column B. 

2. 

AVERAGE(B$2:B$9)

3. Then we subtract the average from each temperature value. For example, within the formula in C2 so far, we would have ... 
4. 

B2-AVERAGE(B$2:B$9)

This is the deviation or deviation from mean. 

5. Next, we square the resulting number. The ^ (caret) is the exponentiation operator. Square the value by raising it to the 2nd power, like this ^2. Now we have the whole formula in C2, which can be copied down through C9 ... 

6. 

=(B2-AVERAGE(B$2:B$9))^2

This gives us a set of squared deviation values. It also eliminates any negative values from the equation. 

7. Sum the squared values ( simply add them all together ) in C9. 

8.  

=SUM(C2:C9)

... giving us the sum of squared deviations. 

9. Now we'll begin the formula in C12 by getting a count of the number of items in the data set ( sometimes called observations ) MINUS 1. 

10.  

COUNT(B2:B9)-1

We'll call this N-1. Just remember this later for an explanation of why we've subtracted 1. 

11. Divide by the sum of squared deviations by (N-1). 

12.   

C10/(COUNT(B2:B9)-1)

In the example here, you should be dividing it by (8-1), or 7. 

13. Take the square root of the whole thing. 

14.   

=SQRT(C10/(COUNT(B2:B9)-1))

Finally, this formula provides the standard deviation. 

If everything is correct, our example will return 14.062513492057. Don't sweat if this isn't the result you have, it won't be necessary. The objective is to help you look into how the standard deviation calculation works. If we can demystify standard deviation, we can understand better how to use it. 

Fortunately - Excel provides a couple of worksheet functions that do ALL this work for us. These are STDEV and STDEVP. We'll look at a real-world example, demonstrating how to implement these, then use it to help explain the difference between the two functions. 

Note : There are other specialized standard deviation functions, such as STDEVA, STDEVPA, DSTDEV and DSTDEVA; however, it's not necessary to cover them within the scope of this overview. 


Applying Standard Deviation 

Entering Excel's standard deviation worksheet function is as simple as ... 

 

=STDEV(B3:B14)


The only parameter needed is the array of original values, such as the periodic temperature measurements in Rows 3 through 14 in our example. 

For a single set of values, standard deviation doesn't tell us much. However, when you harness standard deviation in a comparison of data sets, this can provide a revealing analysis for your data. 

We'll use standard deviation to compare the average monthly temperatures of four southcentral U.S. cities. 

This example illustrates how weather conditions ( at least temperature ) can be more consistent for coastal cities, becoming less consistent as we observe cities further inland. 

The average annual temperatures for these cities are within a fairly narrow range ( less than 10.0°F ) between 58.0°F and 67.9°F. This is shown in Row 16. Unless we have some help from standard deviation calculations, it's difficult to make a comparisons about the consistency of the temperature data between these locations. 

In Row 18, see how the lowest standard deviation of temperatures is 13.5 for Houston and it gets higher as we go inland from the coast to Wichita, having a 19.6 standard deviation value. 

The standard deviation of the monthly temperatures evaluated for cities closer to the coast is lower and, therefore, an indication that those values tend to be more consistant. As we look further inland, the standard deviation of temperatures in those cities grows progressively larger, suggesting these groups of values are less consistant with themselves. 


STDEV vs. STDEVP 

As mentioned earler, standard deviation mainly comes in two flavors: 

· STDEV is used when the group of numbers being evaluated are only a partial sampling of the whole population. The denominator for dividing the sum of squared deviations is N-1, where N is the number of observations ( a count of items in the data set ). Technically, subtracting the 1 is referred to as "non-biased." 

· STDEVP is used when the group of numbers being evaluated is complete - it's the entire population of values. In this case, the 1 is NOT subtracted and the denominator for dividing the sum of squared deviations is simply N itself, the number of observations ( a count of items in the data set ). Technically, this is referred to as "biased." Remembering that the P in STDEVP stands for "population" may be helpful. Since the data set is not a mere sample, but constituted of ALL the actual values, this standard deviation function can return a more precise result. 

Look at the example again, comparing Rows 18 and 21, to see how these calculations return two slightly different standard deviation values for the same data. Notice that the % Err of Mean is lower for STDEVP, which assumes we are evaluating the entire known population. 


COEFFICIENT OF VARIATION 

Notice beneath the STDEV and STDEVP this example calculates a % Err of Mean. This gives us some sense of how much the Average (in Row 16) represents the set of numbers it came from. The formula is: 

Coefficient of Variation = Standard Deviation / Mean 

Therefore, using our example, the Coefficient of Variation calculations divide the STDEV values in Row 18 and the STDEVP values in Row 21 by the Annual AVG in Row 16. 

In this example, it underscores differences between STDEV and STDEVP, as we see the % Err of Mean is lower under the STDEVP calculations than for the STDEV. 


TEXT AND VALUES IN ONE CELL 

Did you know that you could combine text and values in a single cell? 

For example, assume cell A12 contains the value 1435. Enter the following formula into another cell:

="Total: "&A12 

The formula cell will display: "Total: 1435." 

The ampersand is a concatenation operator that joins the text with the contents of cell A12. 

Applying a number format to the cell containing the formula has no effect, because the cell contains text, not a value. As a work-around, modify the formula to use the TEXT function (the second argument for the TEXT function consists of a standard Excel number-format string).

="Total: "&TEXT(A12,"$#,##0.00")

This formula will display "Total: $1,435.00."

Here's another example formula that uses the NOW function to display some text along with the current date and time:

="Report printed on "&TEXT(NOW(),"mmmm d, yyyy at h:mm AM/PM")

PERFORM TWO-WAY TABLE LOOKUPS 

All spreadsheets support lookup functions, tools that return a value from a table by looking up another value in the table. An income tax table is a good example. You can write a formula that uses the VLOOKUP function to determine the tax rate for a given income amount.

The lookup functions in Excel are only appropriate for one-way lookups, however. If you need to perform a two-way lookup, you'll need more than the standard functions. The figure below shows a simple example. 

The formula in cell H4 looks up the entries in cells H2 and H3 and then returns the corresponding value from the table. The formula in H4 is:

=INDEX(A1:E14, MATCH(H2,A1:A14,0), MATCH(H3,A1:E1,0)).

The formula uses the INDEX function, with three arguments. The first is the entire table range (A1:A14). The second uses the MATCH function to return the offset of the desired month in column A. The third argument uses the MATCH function to return the offset of the desired product in row 1.

You may prefer to take advantage of Excel's natural-language formulas. For example, enter the following formula to return Sprocket sales for June:

=June Sprockets 

If natural-language formulas aren't working, select Tools, Options, click the Calculation tab, and place a check mark next to "Accept labels in formulas." Be aware that using natural language formulas is  not 100% reliable! 

AUTOMATIC LIST NUMBERING 

It's fairly easy to create a formula that generates consecutively number items in nonconsecutive cells. Refer to the figure below.

Column A consists of formulas that refer to column B. The formula in cell A1 is:

 =IF(B1<>"",COUNTA($B$1:B1)&".","")

This formula, which is copied down to the other cells in column A, displays the next consecutive item number if the corresponding cell in column B is not empty. If the cell in column B is empty, the formula displays nothing. 

As items are added or deleted from column B, the numbering updates automatically. 

COPY PAGE SETUP SETTINGS TO OTHER SHEETS

Each Excel sheet has its own print setup options (orientation, margins, headers and footers, and so on). These options are specified in the Page Setup dialog box, which you access using the File, Page Setup command. 

When you add a new sheet to a workbook, it contains the default page setup setting. Here's an easy way to transfer the settings from one worksheet to additional worksheets: 

1. Activate the sheet that contains the desired setup info. This is the "source" sheet. 

2. Select the "target" sheets. Press Ctrl and click the sheet tabs of the sheets you want to update with the settings from the source sheet. 

3. Select File, Page Setup and click OK. 

The Page Setup settings of the source sheet will be transferred to all of the target sheets. 

SUMMING AND COUNTING USING MULTIPLE CRITERIA 

If you peruse the Excel newsgroups, you've probably realized that one of the most common questions involves summing or counting using multiple criteria. If your data is set up as a database table you can use database functions such as DCOUNT or DSUM. These functions, however, require the use of a separate criteria range on your worksheet.

This tip provides a number of examples that should solve most of your counting and summing problems. Unlike DCOUNT and DSUM, these formulas don't require a criteria range. 

NOTE: For additional counting techniques, refer to a previous tip. 

The example formulas presented in this tip use the simple database table shown below. You will need to adjust the formulas to account for your own data.

Sum of Sales, where Month="Jan"

This is a straightforward use of the SUMIF function (it uses a single criterion): 

  =SUMIF(A2:A10,"Jan",C2:C10)

Count of Sales, where Month="Jan"

This is a straightforward use of the COUNTIF function (single criterion): 

  =COUNTIF(A2:A10,"Jan")

Sum of Sales, where Month<>"Jan"

Another simple use of SUMIF (single criterion):

  =SUMIF(A2:A10,"<>Jan",C2:C10)

Sum of Sales where Month="Jan" or "Feb"

For multiple OR criteria in the same field, use multiple SUMIF functions:

  =SUMIF(A2:A10,"Jan",C2:C10)+SUMIF(A2:A10,"Feb",C2:C10)

Sum of Sales where Month="Jan" AND Region="North"

For multiple criteria in different fields, the SUMIF function doesn't work. However, you can use an array formula. When you enter this formula, use Ctrl+Shift+Enter:

  =SUM((A2:A10="Jan")*(B2:B10="North")*C2:C10)

Sum of Sales where Month="Jan" AND Region<>"North"

Requires an array formula similar to the previous formula. When you enter this formula, use Ctrl+Shift+Enter:

  =SUM((A2:A10="Jan")*(B2:B10<>"North")*C2:C10)

Count of Sales where Month="Jan" AND Region="North"

For multiple criteria in different fields, the COUNTIF function doesn't work. However, you can use an array formula. When you enter this formula, use Ctrl+Shift+Enter:

  =SUM((A2:A10="Jan")*(B2:B10="North"))

Sum of Sales where Month="Jan" AND Sales>= 200

Requires an array formula similar to the previous example. When you enter this formula, use Ctrl+Shift+Enter:

  =SUM((A2:A10="Jan")*(C2:C10>=200)*(C2:C10))

Sum of Sales between 300 and 400

This also requires an array formula. When you enter this formula, use Ctrl+Shift+Enter:

  =SUM((C2:C10>=300)*(C2:C10<=400)*(C2:C10))

Count of Sales between 300 and 400

This also requires an array formula. When you enter this formula, use Ctrl+Shift+Enter:

  =SUM((C2:C10>=300)*(C2:C10<=400))

FORMAT CELLS TO DISPLAY IN THOUSANDS 

Q. Is there a way to display thousands without zeros? For example, I would like 52,000 to appear as 52.
First, select the cells to be formatted, then choose Format, Cells. Click the Number tab. Select Custom from the Category list, and in the Type box enter 0, (that's a zero followed by a comma).

When this number format is applied, the cells will retain the correct numerical values, but they will be displayed without the last three digits. 

To display values in millions, insert an additional comma at the end of the format string (0,,). 

Another possibility is to display one or more decimal places--for example, 52,100 as 52.1. To do this, include a decimal point in your format string (0.0,). 

You can also use these number formats in charts. To do so, double-click the chart axis to display the Format Axis dialog box. Then click the Number tab and specify the desired format. In Excel 2000 and later, the Scale tab of the Format Axis dialog box lets you specify the unit scaling directly. Just choose Millions from the "Display units" drop-down box. 

ADD GRAPHICS TO YOUR PAGE HEADER 

Note: Excel 2002 has built-in support for graphics in the page header or footer. 

Prior to Excel 2002, a common question was: "How can I insert my company's logo into the page header?" The simple answer: You can't.  But there are a few ways to fake it.

Perhaps the simplest solution is to print your reports on company letterhead -- paper that's preprinted with your logo. Another option is to use a custom font with a character that displays your logo. You can create this custom font using shareware or commercial font creation programs, or hire a professional to do the job. But even professionals will be limited to the use of simple line graphics.

Another way to display a graphic within a page header involves a bit of trickery. Excel lets you specify that one or more rows print at the top of every page (these are known as print titles). You can take advantage of this option and use a print title row to store your logo. 

The figure below shows a graphic that will print at the top of each page. Note that the row height is adjusted to fit the image. 

Here are the basic steps.

First, specify the rows for the print titles. Choose File, Page Setup and click on the Sheet tab in the Page Setup dialog box. This example uses the first two rows as the print titles, so that both the graphic (row 1) and the column headers (row 2) will appear at the top of every printed sheet.

You can also combine standard header options (found in the Header/Footer tab of the Page Setup dialog) with this title rows trick -- but make sure the graphic doesn't obscure the text. For example, if the graphic sits on the left side of the page (as in the example), you'll need to put the page numbers in the right or center sections of the sheet's header.

Now here's where it gets tricky. Click the Print Preview button to preview your worksheet. In the preview window, click the Margins button to display the margin handles, which let you adjust the margins and column widths. Specifically, you'll need to adjust the top margin and the header margin, represented by horizontal lines in the preview window. Normally, the upper horizontal line represents the header margin, and the second horizontal line the top margin. Drag these lines up or down until the page header looks correct. In the figure linked to above, the header margin has been moved above the page margin, so the page margin overlaps with the header margin. The result is that the graphic will align vertically with the normal header text (in the example shown, the page number).

If your worksheet happens to be wider than a page, you'll need to copy the graphic and paste it to the cell that occupies the same location on the subsequent pages.

If all this sounds too complicated, consider upgrading to Excel 2002. 

A HYPOTHETICAL CYCLICAL COMPANY
 

Assume that a hypothetical cyclical company should have reported the following results in millions of dollars for the last 10 periods:  1, 9, 1, 9, 1, 9, 1, 9, 1, 9.   

A Microsoft Excel user should have seen this chart: 
 

Using Microsoft Excel and an 80% confidence level, the summary statistics for a correct report would have been: 

	Correct Statistics

	 
	 

	Mean
	5

	Standard Error
	1.333333333

	Median
	5

	Mode
	1

	Standard Deviation
	4.216370214

	Sample Variance
	17.77777778

	Kurtosis
	-2.571428571

	Skewness
	0

	Range
	8

	Minimum
	1

	Maximum
	9

	Sum
	50

	Count
	10

	Confidence Level(80.0%)
	1.844038403


 

Confidence Level, for Microsoft Excel users, is based upon: 

= CONFIDENCE (alpha, standard_dev, size) 

Estimate the confidence interval for a population mean by a range on either side of a sample mean.  Alpha is the confidence level used to compute the confidence level.  For this study, we used an alpha of 0.20, indicating an 80% confidence level.  Standard_dev is the population standard deviation for the data range (assumed to be known).  Size is the sample size (an integer). 

For the hypothetical cyclical company, we used:  
Alpha = 0.20
Standard_dev = 4.216370214
Size = 10 

The resulting confidence level of 1.844038403 indicates a range of: 

5 + 1.844038403 = 6.844038403 

5 -  1.844038403 = 3.155961597 

